# File: ~/.login
#
# Individual user's login startup file.  
#
# This file first sources a system-administrator-maintained file which 
# sets particular configurations for whatever machine you are logging into.
# With the exception of 'upath', the typical user should not need to modify 
# anything in the first part of this file.  Please read the comments.
#
#                                               Mike McCann
#                                               MBARI 21 Feb 1996
#
# $Id:	.login,v $
# Revision 1.4  98/09/30  08:39:05  08:39:05  vicki (VICKI video software)
# Smarter handling of the start.log file

# Turn debugging message flag on/off (This applies only to .login )
set D = 0

# Set common directory for global sourcing
set COMM1=/usr/local/etc/login
set COMM2=/mbari/login
set COMM3=/usr/mbari/login

# Set file creation mask so that all can read & only owner can write 
umask 022

#
# Execute global.login
#

# Do not touch the next block of code  -  it sets up important stuff!
if (-f $COMM1/global.login) then
	if ($D) echo ".login: sourcing $COMM1/global.login..."
	set COMMON=$COMM1
	source $COMM1/global.login
else if (-f $COMM2/global.login) then
	if ($D) echo ".login: sourcing $COMM2/global.login..."
	set COMMON=$COMM2
	source $COMM2/global.login
else if (-f $COMM3/global.login) then
	if ($D) echo ".login: sourcing $COMM3/global.login..."
	set COMMON=$COMM3
	source $COMM3/global.login
else
	echo "Path and environment not properly defined - Logout and try again."
	echo "If this persists contact your system administrator.  (.login)"
	echo " "
	exit
endif

#
# Define and modify initial path
#

# For security reasons the current directory '.' should always be 
# last. If you need to execute a file in the current directory, then 
# prefix its name with './', e.g. './clear' for a re-defined clear(1) command.
#
# User's path:  If you want to add your own path, uncomment the "#upath = ()"
#               line and add your local path between the ( ).

set upath = ( ~/bin /usr/vw25/bin )

if ( $?upath ) then
    set path = ( $upath $path . )
endif

#
# Define Environment Variables
#

setenv EDITOR /usr/bin/vi

# Should comment the next line out if you use tcsh
setenv SHELL  /bin/csh
setenv MWMSHELL  /bin/sh

# For vims/vicki
setenv VICKI /users/vicki/vicki

#
# Uncomment to use PV-Wave
#
#source /usr/local/vni5/wave/bin/wvsetup
#setenv WAVE_STARTUP /usr/mbari/msis/pvwave/wavestartup
#setenv WAVE_PRODUCT cl

#
# Some do not like the default login prompt that is given.  Here are the
# lines that set up the default; to override, uncomment and modify.
#
#alias setp 'set hwd=$cwd:h;set prompt = "<\! `/bin/hostname`(`uname`) /$hwd:t/$cwd:t> "'
#alias cd 'cd \!*; setp'

# Uncomment to use ArcInfo
#setenv AVHOME /usr/local/esri/arcview2

#
# Source additional files for special applications
#

# Uncomment if you use FERRET
#if ( `uname` == IRIX || `uname` == IRIX64 ) then
#        source /usr/local/etc/ferret_paths
#endif
#if ( `uname` == SunOS ) then
#	switch (`/bin/uname -r`)
#	   	case 5.4:
#			source /local/graphics/ferret_sol/ferret_paths
#			breaksw
#	   	case 4.1.3:
#        		source /local/graphics/ferret/ferret_paths
#			breaksw
#		default:
#			echo "Cannot setup ferret for SunOS", `uname -r`
#			breaksw
#	endsw
#endif

# Set aliases user has defined in their ~/.alias file
if ( -f $HOME/.alias ) then	
	source $HOME/.alias
endif

# Set file completion 
set filec

# If you would like to limit core dump sizes then uncomment the following line:
#limit coredumpsize 8700000

# Setting variable to require the user to be asked if they want a file deleted
set noclobber

# Setting variable so you cannot logout with a ^D
set ignoreeof

#
# Start vicki if start.log file does not exist
#
if ( ! -f start.log ) then
	echo "Starting vicki...."
	/users/vicki/start |& tee start.log
else
	echo "start.log file exists:"
	ls -l start.log
	echo " "
	echo "Enter 'start' if you want to remove it and start vicki: \c"
	set ans = $<
	if ( $?ans == 1 ) then
	    if ( $ans == 'start' ) then
		elm -s "start.log that got left behind" mccann < start.log
		echo "Starting vicki...."
		/users/vicki/start |& tee start.log
	    endif
	endif
endif